# muscles.draw
#
# Praat script that creates figure 2.9 of
#    Boersma (1998): Functional Phonology.
# http://fonsg3.hum.uva.nl/paul/
#
Erase all
Times
10

Create Speaker... s Female 2
Create Artword... a 1
To Art (slice)... 0
Rename... neutral

procedure one row col Muscle$ muscle$ explanation$
   x = 1.5 * (col - 1)
   y = 2.0 * (row - 1)
   Viewport... x x+1.5 y y+1.5
   select Artword a
   Set target... 0 1 'Muscle$'
   To Art (slice)... 0
   plus Speaker s
   Fill inner contour
   select Art neutral
   plus Speaker s
   Dotted line
   Draw
   select Art a
   plus Speaker s
   Plain line
   Draw
   Text top... yes 'muscle$'
   Viewport... x x+1.5 y y+1.7
   Text bottom... yes 'explanation$'
   select Artword a
   Set target... 0 0 'Muscle$'
endproc

call one 1 1 Styloglossus styloglossus tongue back up
call one 1 2 Genioglossus genioglossus tongue forward
call one 1 3 Hyoglossus hyoglossus tongue down
call one 1 4 UpperTongue "upper tongue" tip up
call one 2 1 Sternohyoid sternohyoid larynx down
call one 2 2 Sphincter "pharyngeal constrictors" pharynx narrow
call one 2 3 Stylohyoid stylohyoid larynx up
call one 3 1 Risorius risorius lips spread
call one 3 2 OrbicularisOris "orbicularis oris" lips round
call one 3 3 Masseter masseter jaw closed
call one 3 4 Mylohyoid mylohyoid jaw open

Viewport... 0.2 5.9 0 5.7